-- Dieses Skript zeigt Objektinformationen eines markierten Objektes an.
-- erstellt von Wolfgang Bund am 22.10.97

GetLinkInfo >> fFilename, cLinkTech, sKind, nSize, sPlacedTime, sModTime, sInternalDateMod
GetLinkOptions >> bTextUpdate, bTextAlert, bImageStore, bImageUpdate, bImageAlert
-- bTextUpdate	0 for off   1 for on -2 for option disabled
-- bTextAlert	0 for off   1 for on -2 for option disabled
-- bImageStore	0 for off   1 for on -2 for option disabled
-- bImageUpdate	0 for off   1 for on -2 for option disabled
-- bImageAlert	0 for off   1 for on -2 for option disabled

if sInternalDateMod = ""
   sIMod = ""
else
   sIMod = "Text modifiziert am: "+sInternalDateMod
endif

switch cLinkTech
caseof 0
   sLi = "PageMaker"
   break
caseof 1
   sLi = "Obejkt Link"
   break
caseof 2
   sLi = "OLE"
   break
caseof 3
   sLi = "Abonniert"
   break
endswitch

cL1 = ""

if sKind = "Text"
   switch bTextUpdate
   caseof 0
      cL2 = "Text nicht autom. aktualisieren"
      break
   caseof 1
      cL2 = "Text autom. aktualisieren"
      break
   endswitch

   switch bTextAlert
   caseof 0
      cL3 = "nicht hinweisen vor aktualisieren"
      break
   caseof 1
      cL3 = "hinweisen vor aktualisieren"
      break
   endswitch
else
   switch bImageStore
   caseof 0
      cL1 = "keine Kopie in Satzdatei ablegen"
      break
   caseof 1
      cL1 = "Kopie in Satzdatei ablegen"
      break
   endswitch

   switch bImageUpdate
   caseof 0
      cL2 = "Bild nicht automatisch aktualisieren"
      break
   caseof 1
      cL2 = "Bild automatisch aktualisieren"
      break
   endswitch

   switch bImageAlert
   caseof 0
      cL3 = "nicht hinweisen vor aktualisieren"
      break
   caseof 1
      cL3 = "hinweisen vor aktualisieren"
      break
   endswitch
endif

dialogbegin -75,-50,121,52,fFilename
static 5,4,180,12,"Dateityp: "+sKind
static 5,14,180,22,"Größe: "+quote(nSize)+" Byte"
static 5,24,180,32,"Erstellt am: "+sModTime
static 5,36,180,44,"Linktechnik: "+sLi
static 5,46,180,54,"Plazierungsdatum: "+sPlacedTime
static 5,56,180,64,sIMod
static 5,66,180,74,cL1
static 5,76,180,84,cL2
static 5,86,180,94,cL3
dialogend